@echo off
setlocal enabledelayedexpansion
: !--> Config parameters here <----------------------!
set SSH="c:\Program Files\PuTTY\plink.exe"
set SCP="c:\Program Files\PuTTY\pscp.exe"
set LIST=<список адресов DFL>
set LOGIN=
set PW=
set WHITELIST=<имя файла whitelist>
set MAX_ITEMS=100
: !--------------------------------------------------!
if not exist %SSH% goto NO_PUTTY
if not exist %SCP% goto NO_PUTTY

if "%WHITELIST%" == "" set WHITELIST="%1"
if "%WHITELIST%"=="" (
 echo Usage: DFL_whitelist_all "whitelist"
 exit /b 1
)
if "%LOGIN%" == "" set /P LOGIN=Login:
if "%PW%" == "" set /P PW=Password:

set DEL_SCRIPT=%TEMP%\%RANDOM%~%RANDOM%.sgs
set ADD_SCRIPT=%TEMP%\%RANDOM%~%RANDOM%.sgs

echo cc ALG_HTTP http-whitelist >%DEL_SCRIPT%
for /l %%i in (1,1,%MAX_ITEMS%) do echo delete ALG_HTTP_URL %%i >>%DEL_SCRIPT%

echo cc ALG_HTTP http-whitelist >%ADD_SCRIPT%
echo add ALG_HTTP_URL URL=* -silent -force >>%ADD_SCRIPT%
for /f "tokens=1,*" %%i in (%WHITELIST%) do (
 set url=%%i
 set comment=%%j
 if not "!comment!" == "" (
  set comment=Comments="!comment:"=\"!"
  chcp 65001>nul && (for /f "usebackq tokens=*" %%f in (`echo !comment!`) do set comment=%%f) && chcp 866>nul
 )
 if "!url:/=!" == "!url!" set url=!url!/*
 echo add ALG_HTTP_URL Action=Whitelist URL=!url! !comment! -silent -force >>%ADD_SCRIPT%
 if "!url:~0,4!" == "www." (
  set url=!url:~4!
  echo add ALG_HTTP_URL Action=Whitelist URL=!url! !comment! -silent -force >>%ADD_SCRIPT%
 )
)

for %%i in (%LIST%) do (
 %SSH% -l %LOGIN% -pw %PW% %%i script -remove -name=update.sgs >nul
 %SCP% -l %LOGIN% -pw %PW% %DEL_SCRIPT% %%i:script/update.sgs >nul
 %SSH% -l %LOGIN% -pw %PW% %%i script -execute -name=update.sgs >nul
 %SSH% -l %LOGIN% -pw %PW% %%i script -remove -name=update.sgs >nul
 %SCP% -l %LOGIN% -pw %PW% %ADD_SCRIPT% %%i:script/update.sgs >nul
 echo === %%i ===
 %SSH% -l %LOGIN% -pw %PW% %%i script -execute -name=update.sgs
 %SSH% -l %LOGIN% -pw %PW% %%i activate >nul
 ping -n 8 localhost >nul
 %SSH% -l %LOGIN% -pw %PW% %%i commit
 echo.
)

del %DEL_SCRIPT%
del %ADD_SCRIPT%
exit /b 0

:NO_PUTTY
echo Error. Install PuTTY with pscp and/or correct paths in this file
exit /b 1

URL                           комментарий (русские буквы в кодировке 866)